summaryrefslogtreecommitdiffstats
diff options
context:
space:
mode:
authormh <mh@immerda.ch>2013-11-07 12:01:32 +0100
committermh <mh@immerda.ch>2013-11-07 12:03:03 +0100
commitda5cb04bb3a5bb0f60568534c4a5ddc6978e7ef2 (patch)
tree87514e97796e81728971651435c1d8409cf8c221
init release of my vim config
-rw-r--r--.gitmodules12
-rw-r--r--.netrwhist7
-rw-r--r--.vimrc113
-rw-r--r--autoload/pathogen.vim326
m---------bundle/nerdtree0
m---------bundle/puppet0
m---------bundle/syntastic0
m---------bundle/tabular0
8 files changed, 458 insertions, 0 deletions
diff --git a/.gitmodules b/.gitmodules
new file mode 100644
index 0000000..c31bee1
--- /dev/null
+++ b/.gitmodules
@@ -0,0 +1,12 @@
+[submodule "bundle/puppet"]
+ path = bundle/puppet
+ url = https://github.com/rodjek/vim-puppet.git
+[submodule "bundle/syntastic"]
+ path = bundle/syntastic
+ url = https://github.com/scrooloose/syntastic.git
+[submodule "bundle/tabular"]
+ path = bundle/tabular
+ url = https://github.com/godlygeek/tabular.git
+[submodule "bundle/nerdtree"]
+ path = bundle/nerdtree
+ url = https://github.com/scrooloose/nerdtree.git
diff --git a/.netrwhist b/.netrwhist
new file mode 100644
index 0000000..d0517f9
--- /dev/null
+++ b/.netrwhist
@@ -0,0 +1,7 @@
+let g:netrw_dirhistmax =10
+let g:netrw_dirhist_cnt =5
+let g:netrw_dirhist_1='/home/tgdham10/newcloud/puppetmaster_setup'
+let g:netrw_dirhist_2='/home/tgdham10/newcloud/puppetmaster_setup/modules/puppet/manifests/master'
+let g:netrw_dirhist_3='/home/tgdham10/newcloud/gitlabsetup/modules/gl_bootstrap'
+let g:netrw_dirhist_4='/home/tgdham10/newcloud/gitlabsetup/modules/gitlab/templates/gitlab-shell'
+let g:netrw_dirhist_5='/home/tgdham10/newcloud/puppetmaster_setup/modules/puppet/manifests/master'
diff --git a/.vimrc b/.vimrc
new file mode 100644
index 0000000..13fcfeb
--- /dev/null
+++ b/.vimrc
@@ -0,0 +1,113 @@
+" load 'bundle' manager
+execute pathogen#infect()
+
+syntax on
+set number
+
+"" have the mouse enabled all the time:
+set ruler
+
+filetype plugin indent on
+
+" have command-line completion <Tab> (for filenames, help topics, option names)
+" first list the available options and complete the longest common part, then
+" have further <Tab>s cycle through the possibilities: set wildmode=longest,list,full
+set wildmenu
+set wildignore+=*.o,*.obj,.git,*.pyc,*.svn,*.png,*.jpg,*.gif,*.pdf,*.bak,*.lo
+
+" display the current mode and partially-typed commands in the status line:
+set showmode
+set showcmd
+
+" remove the Toolbar in MacVim
+set guioptions-=T
+colorscheme slate
+
+" use indents of 4 spaces, and have them copied down lines:
+set shiftwidth=2
+set shiftround
+set expandtab
+set autoindent
+set tabstop=2
+set softtabstop=2
+"set textwidth=79
+set smartindent
+set nocompatible
+set shiftround " When at 3 spaces and I hit >>, go to 4, not 5.
+" allow backspacing over everything in insert mode
+set backspace=indent,eol,start
+set history=1000
+
+" disable autowrap
+"set tw=0
+"set nowrapscan
+"set nowrap
+"line wrapping cursor
+"set whichwrap=<,>,h,l,[,]
+
+" make sidescroll smoother
+set sidescroll=3
+" center the cursors on scrolling sidewards
+set sidescrolloff=3
+set backupdir=~/tmp
+set directory=~/tmp " Don't clutter my dirs up with swp and tmp files
+set scrolloff=3 " keep 3 lines visible at top and bottom
+
+let NERDTreeIgnore=['\.pyc$', '\~$', '^\.svn', '\.o$']
+
+let mapleader = ','
+
+nmap <leader>v :e $MYVIMRC<CR>
+" http://stackoverflow.com/questions/2400264/is-it-possible-to-apply-vim-configurations-without-restarting/2400289#2400289
+if has("autocmd")
+ augroup myvimrchooks
+ au!
+ autocmd bufwritepost .vimrc source ~/.vimrc
+ autocmd bufwritepost *.snippets call ReloadAllSnippets()
+ augroup END
+endif
+
+au BufNewFile,BufRead *.mab set filetype=ruby
+au BufNewFile,BufRead *.pp set filetype=puppet
+autocmd FileType ruby,eruby,yaml set ai sw=2 sts=2 et
+autocmd FileType puppet set ai sw=2 sts=2 et
+
+au BufRead /tmp/mutt-* set tw=72
+
+" highlight the searchresults
+set hlsearch
+
+" Highlight the status line --------------------------------------------------
+highlight StatusLine ctermfg=blue ctermbg=yellow
+
+" define `Ispell' language and personal dictionary, used in several places
+" below:
+" set spell
+let IspellLang = 'british'
+let PersonalDict = '~/.ispell_' . IspellLang
+
+" mark character exceeding the 80 limit as errors
+"match Error /\%>80v/
+
+set paste
+
+" FileTypes
+" ==================================================================
+filetype on
+filetype plugin on
+" filetype indent off
+" filetype plugin indent off
+
+" autowrap for .txt and .tex files
+" -------------------------------------------
+"autocmd FileType tex setlocal textwidth=78 wrap linebreak spell
+"autocmd BufRead,BufNewFile *.txt setlocal textwidth=78 wrap linebreak spell
+"autocmd BufRead,BufNewFile *.md setlocal textwidth=78 wrap linebreak spell
+
+nmap <silent> <leader>t :NERDTreeToggle<CR>
+
+" Shortcuts for opening file in same directory as current file {{{2
+map <leader>ew :e <C-R>=expand("%:p:h") . "/" <CR>
+map <leader>es :sp <C-R>=expand("%:p:h") . "/" <CR>
+map <leader>ev :vsp <C-R>=expand("%:p:h") . "/" <CR>
+map <leader>et :tabe <C-R>=expand("%:p:h") . "/" <CR>
diff --git a/autoload/pathogen.vim b/autoload/pathogen.vim
new file mode 100644
index 0000000..7b89cca
--- /dev/null
+++ b/autoload/pathogen.vim
@@ -0,0 +1,326 @@
+" pathogen.vim - path option manipulation
+" Maintainer: Tim Pope <http://tpo.pe/>
+" Version: 2.2
+
+" Install in ~/.vim/autoload (or ~\vimfiles\autoload).
+"
+" For management of individually installed plugins in ~/.vim/bundle (or
+" ~\vimfiles\bundle), adding `execute pathogen#infect()` to the top of your
+" .vimrc is the only other setup necessary.
+"
+" The API is documented inline below. For maximum ease of reading,
+" :set foldmethod=marker
+
+if exists("g:loaded_pathogen") || &cp
+ finish
+endif
+let g:loaded_pathogen = 1
+
+function! s:warn(msg)
+ echohl WarningMsg
+ echomsg a:msg
+ echohl NONE
+endfunction
+
+" Point of entry for basic default usage. Give a relative path to invoke
+" pathogen#incubate() (defaults to "bundle/{}"), or an absolute path to invoke
+" pathogen#surround(). For backwards compatibility purposes, a full path that
+" does not end in {} or * is given to pathogen#runtime_prepend_subdirectories()
+" instead.
+function! pathogen#infect(...) abort " {{{1
+ for path in a:0 ? reverse(copy(a:000)) : ['bundle/{}']
+ if path =~# '^[^\\/]\+$'
+ call s:warn('Change pathogen#infect('.string(path).') to pathogen#infect('.string(path.'/{}').')')
+ call pathogen#incubate(path . '/{}')
+ elseif path =~# '^[^\\/]\+[\\/]\%({}\|\*\)$'
+ call pathogen#incubate(path)
+ elseif path =~# '[\\/]\%({}\|\*\)$'
+ call pathogen#surround(path)
+ else
+ call s:warn('Change pathogen#infect('.string(path).') to pathogen#infect('.string(path.'/{}').')')
+ call pathogen#surround(path . '/{}')
+ endif
+ endfor
+ call pathogen#cycle_filetype()
+ return ''
+endfunction " }}}1
+
+" Split a path into a list.
+function! pathogen#split(path) abort " {{{1
+ if type(a:path) == type([]) | return a:path | endif
+ let split = split(a:path,'\\\@<!\%(\\\\\)*\zs,')
+ return map(split,'substitute(v:val,''\\\([\\,]\)'',''\1'',"g")')
+endfunction " }}}1
+
+" Convert a list to a path.
+function! pathogen#join(...) abort " {{{1
+ if type(a:1) == type(1) && a:1
+ let i = 1
+ let space = ' '
+ else
+ let i = 0
+ let space = ''
+ endif
+ let path = ""
+ while i < a:0
+ if type(a:000[i]) == type([])
+ let list = a:000[i]
+ let j = 0
+ while j < len(list)
+ let escaped = substitute(list[j],'[,'.space.']\|\\[\,'.space.']\@=','\\&','g')
+ let path .= ',' . escaped
+ let j += 1
+ endwhile
+ else
+ let path .= "," . a:000[i]
+ endif
+ let i += 1
+ endwhile
+ return substitute(path,'^,','','')
+endfunction " }}}1
+
+" Convert a list to a path with escaped spaces for 'path', 'tag', etc.
+function! pathogen#legacyjoin(...) abort " {{{1
+ return call('pathogen#join',[1] + a:000)
+endfunction " }}}1
+
+" Remove duplicates from a list.
+function! pathogen#uniq(list) abort " {{{1
+ let i = 0
+ let seen = {}
+ while i < len(a:list)
+ if (a:list[i] ==# '' && exists('empty')) || has_key(seen,a:list[i])
+ call remove(a:list,i)
+ elseif a:list[i] ==# ''
+ let i += 1
+ let empty = 1
+ else
+ let seen[a:list[i]] = 1
+ let i += 1
+ endif
+ endwhile
+ return a:list
+endfunction " }}}1
+
+" \ on Windows unless shellslash is set, / everywhere else.
+function! pathogen#separator() abort " {{{1
+ return !exists("+shellslash") || &shellslash ? '/' : '\'
+endfunction " }}}1
+
+" Convenience wrapper around glob() which returns a list.
+function! pathogen#glob(pattern) abort " {{{1
+ let files = split(glob(a:pattern),"\n")
+ return map(files,'substitute(v:val,"[".pathogen#separator()."/]$","","")')
+endfunction "}}}1
+
+" Like pathogen#glob(), only limit the results to directories.
+function! pathogen#glob_directories(pattern) abort " {{{1
+ return filter(pathogen#glob(a:pattern),'isdirectory(v:val)')
+endfunction "}}}1
+
+" Turn filetype detection off and back on again if it was already enabled.
+function! pathogen#cycle_filetype() " {{{1
+ if exists('g:did_load_filetypes')
+ filetype off
+ filetype on
+ endif
+endfunction " }}}1
+
+" Check if a bundle is disabled. A bundle is considered disabled if it ends
+" in a tilde or its basename or full name is included in the list
+" g:pathogen_disabled.
+function! pathogen#is_disabled(path) " {{{1
+ if a:path =~# '\~$'
+ return 1
+ elseif !exists("g:pathogen_disabled")
+ return 0
+ endif
+ let sep = pathogen#separator()
+ let blacklist = g:pathogen_disabled
+ return index(blacklist, strpart(a:path, strridx(a:path, sep)+1)) != -1 && index(blacklist, a:path) != 1
+endfunction "}}}1
+
+" Prepend the given directory to the runtime path and append its corresponding
+" after directory. If the directory is already included, move it to the
+" outermost position. Wildcards are added as is. Ending a path in /{} causes
+" all subdirectories to be added (except those in g:pathogen_disabled).
+function! pathogen#surround(path) abort " {{{1
+ let sep = pathogen#separator()
+ let rtp = pathogen#split(&rtp)
+ if a:path =~# '[\\/]{}$'
+ let path = fnamemodify(a:path[0:-4], ':p:s?[\\/]\=$??')
+ let before = filter(pathogen#glob_directories(path.sep.'*'), '!pathogen#is_disabled(v:val)')
+ let after = filter(reverse(pathogen#glob_directories(path.sep."*".sep."after")), '!pathogen#is_disabled(v:val[0:-7])')
+ call filter(rtp,'v:val[0:strlen(path)-1] !=# path')
+ else
+ let path = fnamemodify(a:path, ':p:s?[\\/]\=$??')
+ let before = [path]
+ let after = [path . sep . 'after']
+ call filter(rtp, 'index(before + after, v:val) == -1')
+ endif
+ let &rtp = pathogen#join(before, rtp, after)
+ return &rtp
+endfunction " }}}1
+
+" Prepend all subdirectories of path to the rtp, and append all 'after'
+" directories in those subdirectories. Deprecated.
+function! pathogen#runtime_prepend_subdirectories(path) " {{{1
+ call s:warn('Change pathogen#runtime_prepend_subdirectories('.string(a:path).') to pathogen#surround('.string(a:path.'/{}').')')
+ return pathogen#surround(a:path . pathogen#separator() . '{}')
+endfunction " }}}1
+
+" For each directory in the runtime path, add a second entry with the given
+" argument appended. If the argument ends in '/{}', add a separate entry for
+" each subdirectory. The default argument is 'bundle/{}', which means that
+" .vim/bundle/*, $VIM/vimfiles/bundle/*, $VIMRUNTIME/bundle/*,
+" $VIM/vim/files/bundle/*/after, and .vim/bundle/*/after will be added (on
+" UNIX).
+function! pathogen#incubate(...) abort " {{{1
+ let sep = pathogen#separator()
+ let name = a:0 ? a:1 : 'bundle/{}'
+ if "\n".s:done_bundles =~# "\\M\n".name."\n"
+ return ""
+ endif
+ let s:done_bundles .= name . "\n"
+ let list = []
+ for dir in pathogen#split(&rtp)
+ if dir =~# '\<after$'
+ if name =~# '{}$'
+ let list += filter(pathogen#glob_directories(substitute(dir,'after$',name[0:-3],'').'*'.sep.'after'), '!pathogen#is_disabled(v:val[0:-7])') + [dir]
+ else
+ let list += [dir, substitute(dir, 'after$', '', '') . name . sep . 'after']
+ endif
+ else
+ if name =~# '{}$'
+ let list += [dir] + filter(pathogen#glob_directories(dir.sep.name[0:-3].'*'), '!pathogen#is_disabled(v:val)')
+ else
+ let list += [dir . sep . name, dir]
+ endif
+ endif
+ endfor
+ let &rtp = pathogen#join(pathogen#uniq(list))
+ return 1
+endfunction " }}}1
+
+" Deprecated alias for pathogen#incubate().
+function! pathogen#runtime_append_all_bundles(...) abort " {{{1
+ if a:0
+ call s:warn('Change pathogen#runtime_append_all_bundles('.string(a:1).') to pathogen#incubate('.string(a:1.'/{}').')')
+ else
+ call s:warn('Change pathogen#runtime_append_all_bundles() to pathogen#incubate()')
+ endif
+ return call('pathogen#incubate', map(copy(a:000),'v:val . "/{}"'))
+endfunction
+
+let s:done_bundles = ''
+" }}}1
+
+" Invoke :helptags on all non-$VIM doc directories in runtimepath.
+function! pathogen#helptags() abort " {{{1
+ let sep = pathogen#separator()
+ for glob in pathogen#split(&rtp)
+ for dir in split(glob(glob), "\n")
+ if (dir.sep)[0 : strlen($VIMRUNTIME)] !=# $VIMRUNTIME.sep && filewritable(dir.sep.'doc') == 2 && !empty(filter(split(glob(dir.sep.'doc'.sep.'*'),"\n>"),'!isdirectory(v:val)')) && (!filereadable(dir.sep.'doc'.sep.'tags') || filewritable(dir.sep.'doc'.sep.'tags'))
+ silent! execute 'helptags' pathogen#fnameescape(dir.'/doc')
+ endif
+ endfor
+ endfor
+endfunction " }}}1
+
+command! -bar Helptags :call pathogen#helptags()
+
+" Execute the given command. This is basically a backdoor for --remote-expr.
+function! pathogen#execute(...) abort " {{{1
+ for command in a:000
+ execute command
+ endfor
+ return ''
+endfunction " }}}1
+
+" Like findfile(), but hardcoded to use the runtimepath.
+function! pathogen#runtime_findfile(file,count) abort "{{{1
+ let rtp = pathogen#join(1,pathogen#split(&rtp))
+ let file = findfile(a:file,rtp,a:count)
+ if file ==# ''
+ return ''
+ else
+ return fnamemodify(file,':p')
+ endif
+endfunction " }}}1
+
+" Backport of fnameescape().
+function! pathogen#fnameescape(string) abort " {{{1
+ if exists('*fnameescape')
+ return fnameescape(a:string)
+ elseif a:string ==# '-'
+ return '\-'
+ else
+ return substitute(escape(a:string," \t\n*?[{`$\\%#'\"|!<"),'^[+>]','\\&','')
+ endif
+endfunction " }}}1
+
+if exists(':Vedit')
+ finish
+endif
+
+let s:vopen_warning = 0
+
+function! s:find(count,cmd,file,lcd) " {{{1
+ let rtp = pathogen#join(1,pathogen#split(&runtimepath))
+ let file = pathogen#runtime_findfile(a:file,a:count)
+ if file ==# ''
+ return "echoerr 'E345: Can''t find file \"".a:file."\" in runtimepath'"
+ endif
+ if !s:vopen_warning
+ let s:vopen_warning = 1
+ let warning = '|echohl WarningMsg|echo "Install scriptease.vim to continue using :V'.a:cmd.'"|echohl NONE'
+ else
+ let warning = ''
+ endif
+ if a:lcd
+ let path = file[0:-strlen(a:file)-2]
+ execute 'lcd `=path`'
+ return a:cmd.' '.pathogen#fnameescape(a:file) . warning
+ else
+ return a:cmd.' '.pathogen#fnameescape(file) . warning
+ endif
+endfunction " }}}1
+
+function! s:Findcomplete(A,L,P) " {{{1
+ let sep = pathogen#separator()
+ let cheats = {
+ \'a': 'autoload',
+ \'d': 'doc',
+ \'f': 'ftplugin',
+ \'i': 'indent',
+ \'p': 'plugin',
+ \'s': 'syntax'}
+ if a:A =~# '^\w[\\/]' && has_key(cheats,a:A[0])
+ let request = cheats[a:A[0]].a:A[1:-1]
+ else
+ let request = a:A
+ endif
+ let pattern = substitute(request,'/\|\'.sep,'*'.sep,'g').'*'
+ let found = {}
+ for path in pathogen#split(&runtimepath)
+ let path = expand(path, ':p')
+ let matches = split(glob(path.sep.pattern),"\n")
+ call map(matches,'isdirectory(v:val) ? v:val.sep : v:val')
+ call map(matches,'expand(v:val, ":p")[strlen(path)+1:-1]')
+ for match in matches
+ let found[match] = 1
+ endfor
+ endfor
+ return sort(keys(found))
+endfunction " }}}1
+
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Ve :execute s:find(<count>,'edit<bang>',<q-args>,0)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vedit :execute s:find(<count>,'edit<bang>',<q-args>,0)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vopen :execute s:find(<count>,'edit<bang>',<q-args>,1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vsplit :execute s:find(<count>,'split',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vvsplit :execute s:find(<count>,'vsplit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vtabedit :execute s:find(<count>,'tabedit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vpedit :execute s:find(<count>,'pedit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vread :execute s:find(<count>,'read',<q-args>,<bang>1)
+
+" vim:set et sw=2:
diff --git a/bundle/nerdtree b/bundle/nerdtree
new file mode 160000
+Subproject b0bb781fc73ef40365e4c996a16f04368d64fc9
diff --git a/bundle/puppet b/bundle/puppet
new file mode 160000
+Subproject 4e784293f6e36494d6c4578634abc6aca3d2028
diff --git a/bundle/syntastic b/bundle/syntastic
new file mode 160000
+Subproject 2a1659813d6744dd22c0b21c1e1e00a6d8571bb
diff --git a/bundle/tabular b/bundle/tabular
new file mode 160000
+Subproject 60f25648814f0695eeb6c1040d97adca93c4e0b